VP SET SHEET OPTIONS

Home

4D v19


VP SET SHEET OPTIONS ( vpAreaName ; sheetOptions {; sheet} )

Parameter	Typ	Beschreibung
vpAreaName	String	Name des 4D View Pro Bereichs
sheetOptions	Objekt	Für Arbeitsblatt zu setzende Optionen
sheet	Lange Ganzzahl	Arbeitsblatt Nummer (ohne Angabe aktuelles Arbeitsblatt)

Beschreibung

Der Befehl VP SET SHEET OPTIONS definiert verschiedene Optionen für ein Arbeitsblatt des Bereichs vpAreaName.

In vpAreaName übergeben Sie den Namen des 4D View Pro Bereichs. Übergeben Sie einen Namen, der nicht existiert, wird ein Fehler zurückgegeben.

Im Parameter sheetOptions übergeben Sie ein Objekt mit den gewählten Optionen. Die komplette Liste der verfügbaren Optionen finden Sie im Abschnitt 4D View Pro Optionen für Arbeitsblatt.

Im optionalen Parameter sheet können Sie ein bestimmtes Arbeitsblatt angeben (Zählung beginnt bei 0). Ohne Angabe wird standardmäßig das aktuelle Arbeitsblatt verwendet. Mit folgender Konstante können Sie explizit das aktuelle Arbeitsblatt wählen:

Konstante	Wert	Kommentar
vk current sheet	-1	Bestimmt das aktuelle Arbeitsblatt des 4D View Pro Bereichs (Standard)

Beispiel 1

Alle Zellen außer Range C5:D10 schützen:

  // Schutz im aktuellen Arbeitsblatt aktivieren

 C_OBJECT($options)

 $options:=New object

 $options.isProtected:=True

 VP SET SHEET OPTIONS("ViewProArea";$options)

  // Zellen C5:D10 als 'entsperrt' markieren

 VP SET CELL STYLE(VP Cells("ViewProArea";2;4;2;6);New object("locked";False))

Beispiel 2

Sie müssen Ihr Dokument schützen, während Ihre Benutzer Zeilen und Spalten in der Größe verändern können:

 C_OBJECT($options)

 $options:=New object

  // Schutz aktivieren

 $options.isProtected:=True

 $options.protectionOptions:=New object

  // Benutzer das Anpassen von Zeilen erlauben

 $options.protectionOptions.allowResizeRows=True;

  // Benutzer das Anpassen von Spalten erlauben

 $options.protectionOptions.allowResizeColumns=True;

  // Schutz auf das aktuelle Arbeitsblatt anwenden

 VP SET SHEET OPTIONS("ViewProArea";$options)

Beispiel 3

Die Farben im Arbeitsblatt für die Reiter, eingefrorenen Linien, Gitterlinen, Auswahlhintergrund und Auswahlrahmen anpassen:

 C_OBJECT($options)

 $options:=New object

  // Farben von Blatt 1 anpassen

 $options.sheetTabColor:="Black"

 $options.gridline:=New object("color";"Purple")

 $options.selectionBackColor:="rgb(255,128,0,0.4)"

 $options.selectionBorderColor:="Yellow"

 $options.frozenlineColor:="Gold"

 VP SET SHEET OPTIONS("ViewProArea";$options;0)

 

  // Farben des Reiters von Blatt 2 anpassen

 $options.sheetTabColor:="red"

 VP SET SHEET OPTIONS("ViewProArea";$options;1)

 

  // Farben des Reiters von Blatt 3 anpassen

 $options.sheetTabColor:="blue"

 VP SET SHEET OPTIONS("ViewProArea";$options;2)

Das Ergebnis ist:

Beispiel 4

Die Gitterlinien sowie Zeilen- und Spaltentitel ausblenden.

 C_OBJECT($options)

 $options:=New object

 $options.gridline:=New object()

 $options.gridline.showVerticalGridline:=False

 $options.gridline.showHorizontalGridline:=False

 $options.rowHeaderVisible:=False

 $options.colHeaderVisible:=False

 VP SET SHEET OPTIONS("ViewProArea";$options)

Das Ergebnis ist:

Siehe auch

4D View Pro Optionen für Arbeitsblatt
VP Get sheet options